Open Annotations for Rare Diseases (OARD) Knowledge Graph

PREFIX biolink: <https://w3id.org/biolink/vocab/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX hp: <http://purl.obolibrary.org/obo/HP_>

SELECT ?disease ?label ?data_set ?pair_count ?log_odds ?lower_ci ?upper_ci 
WHERE {
  VALUES ?phenotype {hp:0012311}  # Increased total monocyte count
  
    # Find associated phenotypes
    ?assoc biolink:subject ?disease ;
           biolink:object ?phenotype .
    ?disease biolink:category biolink:Disease ;
               rdfs:label ?label .

    # Get study
    ?assoc biolink:has_supporting_studies ?study .
  
    # Get Data Set (currently buried in Count Result. TODO: move to Study node)
    ?study biolink:has_study_results ?results_counts .
    ?results_counts biolink:category biolink:ConceptCountAnalysisResult ;
                    biolink:supporting_data_set ?data_set .
  
    # Get Log Odds Analysis Result
    ?study biolink:has_study_results ?results_log_odds .
    ?results_log_odds biolink:category biolink:LogOddsAnalysisResult ;
              biolink:log_odds_ratio ?log_odds ;
                      biolink:total_sample_size ?pair_count .
  
    # Log odds confidence interval is represented as two unordered values
    ?results_log_odds  biolink:log_odds_ratio_95_ci ?lower_ci , ?upper_ci .
    FILTER(?lower_ci < ?upper_ci) 

    # Use the lower bound of the CI (value closest to 0) as an indication of association strength with high confidence
    BIND(IF(ABS(?lower_ci) < ABS(?upper_ci), ABS(?lower_ci), ABS(?upper_ci)) AS ?dist_to_zero)
}
ORDER BY DESC(?dist_to_zero)
LIMIT 100

PREFIX biolink: <https://w3id.org/biolink/vocab/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mondo: <http://purl.obolibrary.org/obo/MONDO_>
PREFIX ro: <http://purl.obolibrary.org/obo/RO_>

SELECT DISTINCT ?phenotype ?phenotype_label ?oard_predicate ?data_set ?log_odds ?ci1 ?ci2 ?confirming_edge
WHERE {
    VALUES ?disease {mondo:0015691}
    VALUES ?confirming_edge {ro:0004029} # Define the confirming relationship

    # Find OARD associated phenotypes
    ?assoc biolink:subject ?disease ;
           biolink:predicate ?oard_predicate ;
           biolink:object ?phenotype .
    ?phenotype biolink:category biolink:PhenotypicFeature ;
               rdfs:label ?phenotype_label .
    # OARD and Ubergraph each have labels for the phenotype. This filter helps select 1 label
  	FILTER(lang(?phenotype_label) = "en")

    # Confirm with Ubergraph relationship (condition for inclusion)
    ?disease ?confirming_edge ?phenotype .

    # Pull out OARD association data
    ?assoc biolink:has_supporting_studies ?study .
    # Counts Results
    ?study biolink:has_study_results ?results_counts .
    ?results_counts biolink:category biolink:ConceptCountAnalysisResult ;
                    biolink:supporting_data_set ?data_set .
    # Log-Odds Results
    ?study biolink:has_study_results ?results_log_odds .
    ?results_log_odds biolink:category biolink:LogOddsAnalysisResult ;
                  biolink:log_odds_ratio ?log_odds .    
    ?results_log_odds biolink:log_odds_ratio_95_ci ?ci1 , ?ci2 .
    FILTER(?ci1 < ?ci2) 
}
ORDER BY DESC(?log_odds)
LIMIT 100

PREFIX biolink: <https://w3id.org/biolink/vocab/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mondo: <http://purl.obolibrary.org/obo/MONDO_>

SELECT ?phenotype ?phenotype_label ?data_set ?pair_count ?log_odds ?lower_ci ?upper_ci 
WHERE {
  VALUES ?disease {mondo:0007947}  # Marfan syndrome
  
    # Find associated phenotypes
    ?assoc biolink:subject ?disease ;
           biolink:object ?phenotype .
    ?phenotype biolink:category biolink:PhenotypicFeature ;
               rdfs:label ?phenotype_label .

    # Get study
    ?assoc biolink:has_supporting_studies ?study .
  
    # Get Data Set (currently buried in Count Result. TODO: move to Study node)
    ?study biolink:has_study_results ?results_counts .
    ?results_counts biolink:category biolink:ConceptCountAnalysisResult ;
                    biolink:supporting_data_set ?data_set .
  
    # Get Log Odds Analysis Result
    ?study biolink:has_study_results ?results_log_odds .
    ?results_log_odds biolink:category biolink:LogOddsAnalysisResult ;
              biolink:log_odds_ratio ?log_odds ;
                      biolink:total_sample_size ?pair_count .
  
    # Log odds confidence interval is represented as two unordered values
    ?results_log_odds  biolink:log_odds_ratio_95_ci ?lower_ci , ?upper_ci .
    FILTER(?lower_ci < ?upper_ci) 

    # Use the lower bound of the CI (value closest to 0) as an indication of association strength with high confidence
    BIND(IF(ABS(?lower_ci) < ABS(?upper_ci), ABS(?lower_ci), ABS(?upper_ci)) AS ?dist_to_zero)
}
ORDER BY DESC(?dist_to_zero)
LIMIT 100

PREFIX biolink: <https://w3id.org/biolink/vocab/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX hp: <http://purl.obolibrary.org/obo/HP_>

SELECT ?disease ?disease_label 
       (SUM(?best_pair_score) AS ?total_score)
       (GROUP_CONCAT(DISTINCT ?pheno_id; SEPARATOR=", ") AS ?matched_pheno_ids)
       (GROUP_CONCAT(DISTINCT ?pheno_label; SEPARATOR="|") AS ?matched_pheno_labels)
WHERE {
  {
    # INNER QUERY: Find the strongest result per Disease-Phenotype pair
    SELECT ?disease ?phenotype (STR(?phenotype) AS ?pheno_id) ?pheno_label (MAX(?log_odds) AS ?best_pair_score)
    WHERE {
      # Input: Your list of Phenotypes
      VALUES ?phenotype { hp:0012771 hp:0001166 hp:0001657 }

      # Match Association path
      ?assoc biolink:object ?phenotype ;
             biolink:subject ?disease .
      
      ?disease biolink:category biolink:Disease .
      
      # Get Phenotype labels here to pass them up
      OPTIONAL { 
        ?phenotype rdfs:label ?pheno_label . 
      }
      
      # Navigate to stats
      ?assoc biolink:has_supporting_studies/biolink:has_study_results ?stats .
      ?stats biolink:category biolink:LogOddsAnalysisResult ;
             biolink:log_odds_ratio ?log_odds .
    }
    GROUP BY ?disease ?phenotype ?pheno_label
  }

  # Pull the disease label for the final output
  OPTIONAL {
    ?disease rdfs:label ?disease_label .
  }
}
GROUP BY ?disease ?disease_label
ORDER BY DESC(?total_score)
LIMIT 100