ubergraph

Ubergraph

Integrated suite of OBO ontologies with precomputed inferred relationships

462.3M triples

86 classes

1194 properties

14.2M subjects

Overview Example Queries Endpoints Schema

Ubergraph is an RDF triplestore which provides a SPARQL query endpoint to an integrated suite of OBO ontologies, and includes precomputed inferred edges which allow logically complete queries over those ontologies for a subset of OWL. This Proto-OKN copy of the Ubergraph triplestore is provided by the NSF FRINK project.

Get all organisms associated with protein groups (via UniProt)

PREFIX uni: <http://purl.org/weso/uni/uni.html#>
PREFIX re: <http://www.w3.org/2000/10/swap/reason#>
PREFIX ref: <http://purl.org/vocab/relationship/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX uniprot: <http://purl.uniprot.org/uniprot/>
PREFIX uniprot-core: <http://purl.uniprot.org/core/>
PREFIX refs: <https://www.ncbi.nlm.nih.gov/protein/>
PREFIX ncbi: <http://purl.obolibrary.org/obo/NCBITaxon_>
PREFIX refs-uni: <http://purl.uniprot.org/refseq/>
PREFIX ncbi-uni: <http://purl.uniprot.org/taxonomy/>

select ?group ?groupLabel ?organism ?organismLabel {
  {
  ?group rdfs:label ?groupLabel ; skos:member ?member .
bind(iri(replace(str(?member),str(refs:),str(refs-uni:))) as ?member_uni)
  service <https://sparql.uniprot.org/sparql> {
    ?member_uni uniprot-core:organism ?organism_uni .
  }
}
  bind(iri(replace(str(?organism_uni),str(ncbi-uni:),str(ncbi:))) as ?organism)
  ?organism rdfs:label ?organismLabel
} limit 100

graph TD

Run in FRINK

Scientific articles in Wikidata about a cell type that Ubergraph says is part of the abdomen

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wdtn: <http://www.wikidata.org/prop/direct-normalized/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX cell: <http://purl.obolibrary.org/obo/CL_0000000>
PREFIX abdomen: <http://purl.obolibrary.org/obo/UBERON_0000916>
PREFIX part_of: <http://purl.obolibrary.org/obo/BFO_0000050>
SELECT DISTINCT ?cell ?cell_label ?article ?title
WHERE {
  ?cell rdfs:subClassOf cell: .
  ?cell part_of: abdomen: .
  ?wikicell wdtn:P7963 ?cell .
  ?article wdt:P921 ?wikicell .
  ?article rdfs:label ?title .
  ?cell rdfs:label ?cell_label .
}
LIMIT 1000

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v3("?article"):::projected 
  v1("?cell"):::projected 
  v5("?cell_label"):::projected 
  v4("?title"):::projected 
  v2("?wikicell")
  c2([obo:CL_0000000]):::iri 
  c4([obo:UBERON_0000916]):::iri 
  v1 --"rdfs:subClassOf"-->  c2
  v1 --"obo:BFO_0000050"-->  c4
  v2 --"wdtn:P7963"-->  v1
  v3 --"wdt:P921"-->  v2
  v3 --"rdfs:label"-->  v4
  v1 --"rdfs:label"-->  v5

Run in FRINK

Find a study related to influenza and links to other disease sources.

PREFIX schema:   <http://schema.org/>
PREFIX rdf:      <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX oboInOwl: <http://www.geneontology.org/formats/oboInOwl#>

SELECT ?dataset ?datasetName (GROUP_CONCAT(DISTINCT STR(?xref); separator=" | ") AS ?xrefList)
WHERE {
  {
    SELECT ?dataset ?datasetName
    WHERE {
      ?dataset rdf:type schema:Dataset ;
               schema:name ?datasetName ;
               schema:healthCondition <http://purl.obolibrary.org/obo/MONDO_0005812> .
    }
    LIMIT 1
  }

  OPTIONAL {
    <http://purl.obolibrary.org/obo/MONDO_0005812> oboInOwl:hasDbXref ?xref .
  }
}
GROUP BY ?dataset ?datasetName

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v1("?dataset"):::projected 
  v2("?datasetName"):::projected 
  v3("?xref"):::projected 
  v4("?xrefList")
  c5([obo:MONDO_0005812]):::iri 
  c2([schema:Dataset]):::iri 
  v1 --"a"-->  c2
  v1 --"schema:name"-->  v2
  v1 --"schema:healthCondition"-->  c5
  subgraph optional0["(optional)"]
  style optional0 fill:#bbf,stroke-dasharray: 5 5;
    c5 -."oboInOwl:hasDbXref".->  v3
  end
  bind1[/"str(?xref)"/]
  v3 --o bind1
  bind1 --as--o v4

Run in FRINK

Find genes expressed in pancreas acinar cells and regulating cell-matrix adhesion

PREFIX cl: <http://purl.obolibrary.org/obo/CL_>
PREFIX go: <http://purl.obolibrary.org/obo/GO_>
PREFIX ro: <http://purl.obolibrary.org/obo/RO_>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX biolink: <https://w3id.org/biolink/vocab/>

SELECT DISTINCT ?gene ?function {
    ?stmt1 rdf:subject ?gene ; rdf:predicate biolink:functional_association ; rdf:object ?function .
    ?stmt2 rdf:subject ?gene ; rdf:predicate biolink:expressed_in ; rdf:object cl:0002064 .
    ?function ro:0002211 go:0007160 .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v3("?function"):::projected 
  v2("?gene"):::projected 
  v1("?stmt1")
  v4("?stmt2")
  c8([obo:GO_0007160]):::iri 
  c3([biolink:functional_association]):::iri 
  c5([biolink:expressed_in]):::iri 
  c6([obo:CL_0002064]):::iri 
  v1 --"rdf:subject"-->  v2
  v1 --"rdf:predicate"-->  c3
  v1 --"rdf:object"-->  v3
  v4 --"rdf:subject"-->  v2
  v4 --"rdf:predicate"-->  c5
  v4 --"rdf:object"-->  c6
  v3 --"obo:RO_0002211"-->  c8

Run in FRINK

Cell types in abdominal organs

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX cell: <http://purl.obolibrary.org/obo/CL_0000000>
PREFIX organ: <http://purl.obolibrary.org/obo/UBERON_0000062>
PREFIX abdomen: <http://purl.obolibrary.org/obo/UBERON_0000916>
PREFIX part_of: <http://purl.obolibrary.org/obo/BFO_0000050>
SELECT DISTINCT ?cell ?cell_label ?organ ?organ_label
WHERE {
  ?cell rdfs:subClassOf cell: .
  ?cell part_of: ?organ .
  ?organ rdfs:subClassOf organ: .
  ?organ part_of: abdomen: .
  ?cell rdfs:label ?cell_label .
  ?organ rdfs:label ?organ_label .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v1("?cell"):::projected 
  v3("?cell_label"):::projected 
  v2("?organ"):::projected 
  v4("?organ_label"):::projected 
  c2([obo:CL_0000000]):::iri 
  c4([obo:UBERON_0000062]):::iri 
  c5([obo:UBERON_0000916]):::iri 
  v1 --"rdfs:subClassOf"-->  c2
  v1 --"obo:BFO_0000050"-->  v2
  v2 --"rdfs:subClassOf"-->  c4
  v2 --"obo:BFO_0000050"-->  c5
  v1 --"rdfs:label"-->  v3
  v2 --"rdfs:label"-->  v4

Run in FRINK

What is the adrenal gland part of?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX adrenal_gland: <http://purl.obolibrary.org/obo/UBERON_0002369>
PREFIX part_of: <http://purl.obolibrary.org/obo/BFO_0000050>
SELECT DISTINCT ?x ?x_label
WHERE {
  adrenal_gland: part_of: ?x .
  ?x rdfs:label ?x_label .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v1("?x"):::projected 
  v2("?x_label"):::projected 
  c1([obo:UBERON_0002369]):::iri 
  c1 --"obo:BFO_0000050"-->  v1
  v1 --"rdfs:label"-->  v2

Run in FRINK

Processes that output glucose

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX CHEBI: <http://purl.obolibrary.org/obo/CHEBI_>
PREFIX has_output: <http://purl.obolibrary.org/obo/RO_0002234>
SELECT ?process ?label
WHERE {
  ?process has_output: CHEBI:17234 .
  ?process rdfs:label ?label .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v2("?label"):::projected 
  v1("?process"):::projected 
  c2([obo:CHEBI_17234]):::iri 
  v1 --"obo:RO_0002234"-->  c2
  v1 --"rdfs:label"-->  v2

Run in FRINK

SPARQL Endpoint	`https://frink.apps.renci.org/ubergraph/sparql`
Triple Pattern Fragments	`https://frink.apps.renci.org/ldf/ubergraph`

Open in FRINK Query UI

Classes (86) Properties (1194)

Class	Entities

Property	Triples